Pontos de Entrada do Importador de XML Protheus

User Function GT1DIVPD()

Local aDiver := PARAMIXB[1]

Local nI := 0

Local nValorXml := 0

Local nValorPed := 0

Local nDiferenca := 0

Local nToler := 0

   

    For nI := 1 To Len(aDiver)

        If "VALOR" $ Upper(aDiver[nI][1])

            nValorXml := Val(StrTran(aDiver[nI][8],",","."))

            nValorPed := Val(StrTran(aDiver[nI][9],",","."))

            nDiferenca := Abs(nValorXml - nValorPed)

            nToler := ((1 / 100) * nValorPed)

            If nDiferenca <= nToler

                aDiver[nI][1] := "DELETAR"

            EndIf

        EndIf

    Next nI

    nI := 1

    Do While Len(aDiver) > 0

        If nI > Len(aDiver)

            Exit

        EndIf

        If aDiver[nI][1] == "DELETAR"

            aDel(aDiver,nI)

            aSize(aDiver,Len(aDiver)-1)

        Else

            nI++

        EndIf

    EndDo

Return aDiver

User Function GT1CLIFOR()

Local lCliente := (PARAMIXB[1] == "2")

Local cWhere := ""

// Parametro para indicar códigos não utilizados

// Exemplo com código + loja

// "'01234501','09876502',..."

Local cCodigos := GetNewPar("MV_????","")

    // Condição somente na busca de fornecedores

    If !lCliente

        cWhere := " AND SA2.A2_COD + SA2.A2_LOJA NOT IN ("+cCodigos+")"

    EndIf

Return cWhere

User Function GT1NFRET()

Local nItem := PARAMIXB[1]

Local aRet := {"",{}}

Local cxPed := ""

Local nItemPed := ""

Local oXmlMan := Nil

    // Retorna o objeto TXmlManager do Xml

    oXmlMan := U_CXTranXml( (_cTab1)->&(_cCmp1 + "_XML") )

   

    // Posiciona na tag <xPed> com função do ConexãoNF-e

    If U_CXPosXML(oXmlMan,Separa(">nfeProc/>NFe/>infNFe/?det@nItem="+cValtoChar(nItem)+"/?prod/?xPed","/"))

        // Captura conteúdo da tag posicionada

        cxPed := oXmlMan:cText

        // Verifica se tem mais uma tag

        If oXmlMan:DOMHasNextNode()

            // Posiciona na próxima tag

            oXmlMan:DOMNextNode()

            // Captura a informação da tag posicionada, que deve ser <nItemPed>

            nItemPed := oXmlMan:cText

        EndIf

    EndIf

    If !Empty(cxPed) .And. !Empty(nItemPed)

        // Informações que deve ser retornadas:

        // aRet[1] = Código do produto

        // aRet[2] = array com informaçãoes da SD2:

        //           aAdd(aNotas,{D2_DOC,D2_SERIE,D2_CLIENTE,D2_LOJA,D2_COD,D2_ITEM,B6_SALDO,D2_PRCVEN,D2_NUMSEQ,D2_LOTECTL,D2_DTVALID,D2_TES,D2_IDENTB6,D2_LOCAL,D2_VALIPI,D2_EMISSAO,0})

       

    EndIf

Return aRet

User Function GT1VLPRD()

Local aAreaAnt := GetArea()

Local nTipoVld := PARAMIXB[1] // 1=NCM, 2=Origem, 3=CEST, 4=EAN, 5=CFOP

Local aItens := PARAMIXB[2] // Itens da grid

Local nLinha := PARAMIXB[3] // Linha posicionada

Local lRet := .T.

    Do Case

        Case nTipoVld == 1 // NCM

            // Quando o tipo de produto for ATIVO IMOBILIZADO|BENEFICIAMENTO|EMBALAGEM, não faz validação do NCM

            If Posicione("SB1",1,xFilial("SB1") + aItens[nLinha][_nPosProdu],"B1_TIPO") $ "AI|BN|EM"

                lRet := .F.

            Endif

        Case nTipoVld == 2 // Origem

        Case nTipoVld == 3 // CEST

        Case nTipoVld == 4 // EAN

        Case nTipoVld == 5 // CFOP

        Otherwise

            lRet := .T.

    EndCase

RestArea(aAreaAnt)

Return lRet

User Function GT1BRWCHG()

    // Seta o tipo de frete para CIF
    cCombo2 := "C"

Return

User Function GT1FILBRW()

Local cFiltro := ""

   

    // Ignora notas de um determinado fornecedor

    cFiltro := " AND Z1_CGCEMI NOT IN ('12345678910123','98765432109876')"

Return cFiltro

User Function GT1CMPCT()

Local aFields := {}

    aAdd(aFields,{;

        {"Classe Valor","DX_CLVL","@!",TamSx3("D1_CLVL")[1],0,"",,"C","CTH",},; // {X3_TITULO,X3_CAMPO,X3_PICTURE,X3_TAMANHO,X3_DECIMAL,X3_VALID,X3_USADO,X3_TIPO,X3_F3,X3_CONTEXT}

        {"D1_CLVL"/*Campo SD1*/,""/*Valor Padrão*/};

    })

    aAdd(aFields,{;

        {"Item CTa","DX_ITEMCTA","@!",TamSx3("D1_ITEMCTA")[1],0,"",,"C","CTD",},; // {X3_TITULO,X3_CAMPO,X3_PICTURE,X3_TAMANHO,X3_DECIMAL,X3_VALID,X3_USADO,X3_TIPO,X3_F3,X3_CONTEXT}

        {"D1_ITEMCTA"/*Campo SD1*/,""/*Valor Padrão*/};

    })

    aAdd(aFields,{;

        {"Conta Contábil","DX_CONTA","@!",TamSx3("D1_CONTA")[1],0,"",,"C","CT1",},; // {X3_TITULO,X3_CAMPO,X3_PICTURE,X3_TAMANHO,X3_DECIMAL,X3_VALID,X3_USADO,X3_TIPO,X3_F3,X3_CONTEXT}

        {"D1_CONTA"/*Campo SD1*/,""/*Valor Padrão*/};

    })

Return aFields

User Function GT1PCAUT()

Local aPedPE := {}

Local cQuery := ""

Local cAliasSC7 := ""

Local cRestNFe := SuperGetMV("MV_RESTNFE")

    cQuery := " SELECT SC7.R_E_C_N_O_ RECNOC7"

    cQuery +=   " FROM " + RetSqlName("SC7") + " SC7"

    cQuery +=  " WHERE SC7.C7_FILENT = '" + xFilial("SC7") + "'"

    If cRestNFe == "S"

        cQuery += " AND SC7.C7_CONAPRO NOT IN ('B','R')"

    Endif

    // Verifica se tem saldo

    cQuery +=    " AND (SC7.C7_QUANT - SC7.C7_QUJE - SC7.C7_QTDACLA) > 0"

    cQuery +=    " AND SC7.C7_RESIDUO = ' '"

    cQuery +=    " AND SC7.C7_TPOP <> 'P'"

    cQuery +=    " AND SC7.D_E_L_E_T_ = ' '"

    cQuery +=  " ORDER BY C7_NUM, C7_PRODUTO, C7_DATPRF, C7_ITEM"

    cQuery := ChangeQuery(cQuery)

    cAliasSC7 := GetNextAlias()

    dbUseArea(.T., "TOPCONN", TcGenQry(, , cQuery), cAliasSC7, .F., .T.)

    Do While (cAliasSC7)->(!Eof())

        SC7->(dbGoTo( (cAliasSC7)->RECNOC7 ))

       

        aAdd(aPedPE, {.F.,;    // 1

            SC7->C7_NUM,;      // 2

            SC7->C7_ITEM,;     // 3

            SC7->C7_EMISSAO,;  // 4

            SC7->C7_PRODUTO,;  // 5

            SC7->C7_UM,;       // 6

            (SC7->C7_QUANT - SC7->C7_QUJE - SC7->C7_QTDACLA),; // 7

            SC7->C7_DESCRI,;   // 8

            SC7->C7_PRECO,;    // 9

            SC7->C7_TES,;      // 10

            SC7->C7_PICM,;     // 11

            SC7->C7_IPI,;      // 12

            0,;                // 13

            SC7->C7_LOJA,;     // 14

            SC7->C7_COND,;     // 15

            SC7->C7_DATPRF,;   // 16

            SC7->C7_ITEMGRD,;  // 17

            SC7->C7_VLDESC})   // 18

        (cAliasSC7)->(dbSkip())

    EndDo

    (cAliasSC7)->(dbCloseArea())

    If Len(aPedPE) == 0

        // Altera para nulo para o sistema procurar de forma padrão.

        aPedPE := Nil

    EndIf

Return aPedPE

User Function GT1INIT()

    MsAguarde({|| Processo() }, "Carregando Registros", "Sincronização produto x fornecedor (ZB0 x ZC6)")

Return Nil

User Function GT1PEDCT()

Local aAreaAnt := GetArea()

Local cQuery := ''

Local cAliasQry := ''

Local aPedCTE := {}

    cQuery := "SELECT SC7.C7_NUM,"

    cQuery +=       " SC7.C7_ITEM,"

    cQuery +=       " SC7.C7_PRODUTO,"

    cQuery +=       " SC7.C7_DESCRI"

    cQuery +=  " FROM " + RetSqlName('ZZU') + " ZZU"

    cQuery += " INNER JOIN " + RetSqlName('SC7') + " SC7"

    cQuery +=    " ON SC7.C7_FILENT = '" + xFilial('SC7') + "'"

    cQuery +=   " AND SC7.C7_NUM = ZZU.ZZU_PC"

    cQuery +=   " AND SC7.C7_ITEM = '0001'"

    cQuery +=   " AND SC7.D_E_L_E_T_ = ' '"

    cQuery += " WHERE ZZU.ZZU_FILIAL = '" + xFilial('ZZU') + "'"

    cQuery +=   " AND ZZU.ZZU_NUMPF = '" + (_cTab1)->&(_cCmp1 + "_PEDFRT") + "'"

    cQuery +=   " AND ZZU.ZZU_SEQ = " + cValToChar( (_cTab1)->&(_cCmp1 + "_SEQFRT") )

    cQuery +=   " AND ZZU.D_E_L_E_T_ = ' '"

    cQuery := ChangeQuery(cQuery)

    cAliasQry := GetNextAlias()

    dbUseArea(.T., 'TOPCONN', TcGenQry(, , cQuery), cAliasQry, .F., .T.)

    If (cAliasQry)->(!Eof())

        (cAliasQry)->( aAdd(aPedCTE,{""/*Chave*/,C7_NUM,C7_ITEM,C7_PRODUTO,C7_DESCRI, (_cTab1)->&(_cCmp1 + "_TOTVAL") }) )

       

    EndIf

    (cAliasQry)->(dbCloseArea())

RestArea(aAreaAnt)

Return aPedCTE

User Function GT1VLNFS()

MsgAlert("Validação do PE GT1VLNFS")

Return .F.

User Function GT1CMPLT()

Local aCampos := {}

    //            Tabela, Campo      , Título    , F3  , Nil <reservado para conteúdo>

    aAdd(aCampos,{"SF1" ,"F1_MENNOTA","Observ."  ,""   ,Nil})

    aAdd(aCampos,{"SD1" ,"D1_OP"     ,"Cod. OP"  ,"SC2",Nil})

    aAdd(aCampos,{"SD1" ,"D1_XDESCRI","Desc. XML",""   ,Nil})

    aAdd(aCampos,{"SD1" ,"D1_XUM"    ,"UM XML"   ,""   ,Nil})

    aAdd(aCampos,{"SD1" ,"D1_XQTDE"  ,"Qtde. XML",""   ,Nil})

    aAdd(aCampos,{"SD1" ,"D1_DTVALID","Dt. Valid",""   ,Nil})

Return aCampos

User Function GTNUMNFS()

Local cNumNFS := Paramixb

Local cNumAux := ""

Local cNumAux2 := ""

    If Len(cNumNFS) > 9

        cNumAux := SubStr(cNumNFS,1,4)

   

        // Pega as 9 posições da direita para esquerda

        cNumAux2 := Right(Alltrim(cNumNFS),9)

        // Remove zeros a esquerda

        Do While Len(cNumAux2) > 0 .And. SubStr(cNumAux2,1,1) == "0"

            cNumAux2 := SubStr(cNumAux2,2)

        EndDo

        // Incrementa 2021 + 503 = 2021503

        cNumAux += PadL(AllTrim(cNumAux2),5,"0")

    Else

        cNumAux := cNumNFS

    EndIf

   

Return cNumAux

User Function CXMANDOC()

Local cDoc := PARAMIXB[1] // Número do documento

Local cXml := PARAMIXB[2] // XML

Local cTipo := PARAMIXB[3] // Tipo de XML 1=NFe;2=CTe;4=NFSe;5=Cancelamento;6=CTe OS

Local cCNPJ := ""

    If cTipo == "4" // NFSe

        // Captura o CNPJ do tomador do XML NFSe

        cCNPJ := U_CXCgcDe(cXml,cTipo)

        // Manipula os zeros a esquerda

        If AllTrim(SubStr(cCNPJ,1,8)) == "01234567"

            // Retira os zeros a esquerda

            Do While Len(cDoc) > 0 .And. SubStr(cDoc,1,1) == "0"

                cDoc := SubStr(cDoc,2)

            EndDo

        EndIf

    EndIf

Return cDoc

User Function CXMANSER()

Local cSerie := PARAMIXB[1]

Local cXml   := PARAMIXB[2]

Local cTipo  := PARAMIXB[3]

Local cCNPJ := ""

Local oXmlMan := U_CXTranXml(cXml) // Instancia o objeto do XML

    If cTipo == "1" // NFe

        // Captura o CNPJ do emissor do XML NFe

        If Empty(cCNPJ := U_CXSeekXml(oXmlMan,Separa(">nfeProc/>NFe/>infNFe/?emit/?CNPJ","/")))

            cCNPJ := U_CXSeekXml(oXmlMan,Separa(">nfeProc/>NFe/>infNFe/?emit/?CPF","/"))

        EndIf

        // Manipula a série para o fornecedor x

        If AllTrim(cCNPJ) == "01234567891234"

            // Adiciona zeros a esquerda

            cSerie := PadL(AllTrim(cSerie),3,"0")

        EndIf

    EndIf

Return cSerie

User Function CXNFDESX()

Local aAreaAnt := GetArea()

Local lOk := .T.

Local cTab1 := ""

Local cCmp1 := ""

Local cTipoXml := ""

    cTab1 := Upper(AllTrim(GetNewPar("MV_XGTTAB1", ""))) // Cabecalho XML

    cCmp1 := IIf(SubStr(cTab1, 1, 1) == "S", SubStr(cTab1, 2, 2), cTab1)

   

    cTipoXml := (cTab1)->&(cCmp1 + "_TIPO")

    If cTipoXml == "1" // NFe

       

        // [...]

       

        If !lOk

            // Altera situação do XML para 0=Desconsiderado

            RecLock(cTab1,.F.)

            (cTab1)->&(cCmp1 + "_SIT") := "0" // Desconsiderado

            (cTab1)->&(cCmp1 + "_CCECOR") := "XML desconsiderado por se tratar de Encargos de Transmissão"

            (cTab1)->(MsUnLock())

        EndIf

    EndIf

RestArea(aAreaAnt)

Return lOk

User Function CXVALXML()

Local aAreaAnt := GetArea()

Local aRet := {.T.,""}

Local cTab1 := ""

Local cCmp1 := ""

Local dDtEmis := Nil

Local nTipo := "1"

Local cForMail := ""

Local cTextoEml := ""

    cTab1 := Upper(AllTrim(GetNewPar("MV_XGTTAB1", ""))) // Cabecalho XML

    cCmp1 := IIf(SubStr(cTab1, 1, 1) == "S", SubStr(cTab1, 2, 2), cTab1)

    dDtEmis := (cTab1)->&(cCmp1 + "_DTEMIS")

    nTipo := (cTab1)->&(cCmp1 + "_TIPO") // 1 = NFe, 2 = CTe, 4 = NFSe

    // Quando a nota for emitida depois do dia 25, envia notificação para o fornecedor

    If nTipo $ "1|4" .And. Day(dDtEmis) > 25 .And. Day(dDtEmis) <= 31

        cForMail := AllTrim(Posicione("SA2",1,xFilial("SA2") + (cTab1)->&(cCmp1 + "_CODEMI") + (cTab1)->&(cCmp1 + "_LOJEMI"),"A2_EMAIL"))

        cTextoEml := GetNewPar("MV_XGTMSGE","")

        cTextoEml := Mensagem(cTextoEml,cTab1,cCmp1)

        If (cTab1)->(U_CXFieldP(cCmp1 + "_EMLFOR")) == 0

            MsgAlert("Não foi encontrado o campo " + cCmp1 + "_EMLFOR" + " para notificação de e-mail ao fornecedor.", "E-mail ao Fornecedor")

        Else

            // Só envia a primeira vez

            If Empty((cTab1)->&(cCmp1 + "_EMLFOR")) .Or. (cTab1)->&(cCmp1 + "_EMLFOR") == "2"

                // Envia o e-mail para fornecedor cadastrado na SA2

                If EnvEmail(cForMail,cTextoEml)

                    // Marca como e-mail já enviado

                    RecLock(cTab1,.F.)          

                    (cTab1)->&(cCmp1 + "_EMLFOR") := "1" // Sim

                    (cTab1)->(MsUnlock())

                Else

                    // Marca como e-mail ainda não enviado

                    RecLock(cTab1,.F.)          

                    (cTab1)->&(cCmp1 + "_EMLFOR") := "2" // Não

                    (cTab1)->(MsUnlock())

                EndIf

            EndIf

        EndIf

        aRet := {.F.,"Emissão posterior ao dia 25."}

    EndIf

RestArea(aAreaAnt)

Return aRet

User Function GT1OPDF()

Reclock("AC9",.F.)
AC9->AC9_CODOBJ := "Alterado"
AC9->(MsUnlock())

Return Nil

User Function GTAVICMS()

Local cRetOp := Nil

    // Verifica o código da TES digitado, caso seja para consumo próprio, altera para sempre

    // manter o valor digitado em tela (valor ICMS igual a zero)

    If M->&(_cCmp1 + "_TES") == "173"

        cRetOP := "1" // Manter digitado

    EndIf

Return cRetOP

User Function GT1CPRPA()

Local aCampos := ""

    // aCampos[x][1] -> Campo da tabela 8 [Regra Automática]

    // aCampos[x][2] -> Nome da tabela de referência [SB1 ou SC7]

    // aCampos[x][3] -> Nome do campo da tabela de referencia

    aCampos := { {"ZA8_ESTOQ" , "SB1", "B1_ESTOQUE"},;

                {"ZA8_APLICA", "SC7", "C7_APLIC"} }

Return aCampos

User Function CXEMPAUT()

Local cConteudo := ""

    // Formato <empresa><filial>, onde 99 é empresa e 01 a filial

    cConteudo := "9901;9902"

Return cConteudo